FileFunctions.vb

Imports System.IO
Imports System.Threading

Public Structure FolderSelect
    Private FullFilePath As String
    Private DriveName As String
    Private FolderNameArr() As String
    Private IsFilePath As Boolean
    Private maxIndex As Integer
    Private _CurrentIndex As Integer

    Public SelectedFolder As String

    Public ReadOnly initialized As Boolean
    Public Sub New(fullPath As String)
        FullFilePath = fullPath
        DriveName = Path.GetPathRoot(FullFilePath)

        Dim str As String
        If DriveName.EndsWith("\") Then
            str = FullFilePath.Substring(DriveName.Length)
        Else
            str = FullFilePath.Substring(DriveName.Length + 1)
        End If

        FolderNameArr = str.Split("\"c)

        initialized = True

        Dim longPath As String
        If FullFilePath.Substring(0, 2) <> "\\" Then
            longPath = "\\?\" & FullFilePath
        Else
            longPath = "\\?\UNC\" & FullFilePath.Remove(0, 2)
        End If

        If File.Exists(longPath) = True Then
            IsFilePath = True
            maxIndex = FolderNameArr.Length - 2
        Else
            IsFilePath = False
            maxIndex = FolderNameArr.Length - 1
        End If

        _CurrentIndex = maxIndex
    End Sub

    Public ReadOnly Property CurrentIndex As Integer
        Get
            Return _CurrentIndex
        End Get
    End Property


    Public ReadOnly Property OriginalFilePath As String
        Get
            Return FullFilePath
        End Get
    End Property

    Public ReadOnly Property CurrentFolder(Optional mode As String = "[folder,fullPath,parentFolder]") As String
        Get
            Select Case mode
                Case "[folder,fullPath,parentFolder]", "folder"
                    Return FolderNameArr(_CurrentIndex)
                Case "fullPath"
                    Dim arr() As String = FolderNameArr.Take(_CurrentIndex + 1).Prepend(DriveName).ToArray
                    Return Path.Combine(arr)
                Case "parentFolder"
                    Dim arr() As String

                    If _CurrentIndex > 0 Then
                        arr = FolderNameArr.Take(_CurrentIndex).Prepend(DriveName).ToArray
                    Else
                        arr = {DriveName}
                    End If

                    Return Path.Combine(arr)
                Case Else
                    Stop
                    Return ""
            End Select

        End Get
    End Property

    Public ReadOnly Property FullFoldersPath As String
        Get
            If IsFilePath = True Then
                Return Path.GetDirectoryName(FullFilePath)
            Else
                Return FullFilePath

            End If
        End Get
    End Property
    Public ReadOnly Property FolderArr As String()
        Get
            Return FolderNameArr.Take(maxIndex + 1).ToArray
        End Get
    End Property


    Public Function SwitchFolder(mode As String) As String
        Select Case mode
            Case "up"
                If _CurrentIndex > 0 Then
                    _CurrentIndex -= 1
                End If
            Case "down"
                If _CurrentIndex < maxIndex Then
                    _CurrentIndex += 1
                End If
            Case Else
                Stop
        End Select

        Return FolderNameArr(_CurrentIndex)
    End Function

End Structure

Public Structure UndoData
    Public OriginalPath As String

    Public newName As String
    Public mode As String
    Public newList As Boolean

    Public ReadOnly Property newPath As String
        Get
            Return Path.Combine(Path.GetDirectoryName(OriginalPath), newName)
        End Get
    End Property

    Public ReadOnly Property OriginalName As String
        Get
            Return Path.GetFileName(OriginalPath)
        End Get
    End Property

End Structure


Module FileFunctions
    Public Function GetLongFilePaths2(FolderPath As String, SearchSubFolders As Boolean, MaxPathLength As Integer, ByRef completePathArr() As String,
                                      ByRef FileScanCount As Integer, token As CancellationToken, ByRef searchException As Exception) As String()

        FileScanCount = 0
        Dim filteredList As New List(Of String), fullList As New List(Of String)

        Try
            Dim opt As System.IO.SearchOption = If(SearchSubFolders, SearchOption.AllDirectories, SearchOption.TopDirectoryOnly)

            For Each filePath As String In Directory.EnumerateFiles(FolderPath, "*", opt)
                If filePath.Length > MaxPathLength Then
                    filteredList.Add(filePath)
                End If
                fullList.Add(filePath)
                FileScanCount += 1
                token.ThrowIfCancellationRequested()
            Next

        Catch ex As OperationCanceledException
            'continue
        Catch ex As Exception
            searchException = ex
        End Try

        completePathArr = fullList.ToArray
        Return filteredList.ToArray
    End Function

    Public Function GetLongFilePaths3(FolderPath As String, SearchSubFolders As Boolean, MaxPathLength As Integer, ByRef completePathArr() As String,
                                  ByRef FileScanCount As Integer, token As CancellationToken, searchExceptionList As List(Of Exception)) As String()

        FileScanCount = 0
        Dim filteredList As New List(Of String)
        Dim fullList As New List(Of String)

        Try
            EnumerateFilesRecursive(FolderPath, SearchSubFolders, MaxPathLength, filteredList, fullList, FileScanCount, token, searchExceptionList)
        Catch ex As OperationCanceledException
            ' Cancelled by user — return whatever was collected so far
        End Try

        completePathArr = fullList.ToArray()
        Return filteredList.ToArray()
    End Function

    Private Sub EnumerateFilesRecursive(folderPath As String, recurse As Boolean, MaxPathLength As Integer, filteredList As List(Of String), fullList As List(Of String),
                                     ByRef scanCount As Integer, token As CancellationToken, searchExceptionList As List(Of Exception))

        ' --- Enumerate files in the current folder ---
        Dim files As IEnumerable(Of String)
        Try
            files = Directory.EnumerateFiles(folderPath, "*", SearchOption.TopDirectoryOnly)
        Catch ex As Exception
            searchExceptionList.Add(ex)
            Return
        End Try

        For Each filePath As String In files
            token.ThrowIfCancellationRequested()
            fullList.Add(filePath)
            scanCount += 1
            If filePath.Length > MaxPathLength Then
                filteredList.Add(filePath)
            End If
        Next

        If recurse = False Then Return

        Dim subFolders As IEnumerable(Of String)
        Try
            subFolders = Directory.EnumerateDirectories(folderPath)

        Catch ex As Exception
            searchExceptionList.Add(ex)

            Return
        End Try

        For Each subFolder As String In subFolders
            token.ThrowIfCancellationRequested()
            EnumerateFilesRecursive(subFolder, recurse, MaxPathLength, filteredList, fullList, scanCount, token, searchExceptionList)
        Next
    End Sub

    Public Function ShowInExplorer(filePath As String) As Boolean

        Dim argument As String
        If filePath.Length > 259 Then
            filePath = Path.GetDirectoryName(filePath)
            If filePath.Length > 259 Then
                Return False
            Else
                argument = $"/expand,""{filePath}"""
            End If
        Else
            argument = $"/select,""{filePath}"""
        End If

        If IO.File.Exists(filePath) Or IO.Directory.Exists(filePath) Then
            Process.Start("explorer.exe", argument)
        Else
            Return False
        End If

        Return True
    End Function

    Public Function ChangeFileName(filePath As String, newName As String, folderMode As Boolean) As String

        If newName = "" Then
            Return "File name is empty"
        ElseIf newName = Path.GetFileName(filePath) Then
            Return "File or folder name is not new."
        End If

        Dim parentFolderPath As String = Path.GetDirectoryName(filePath)
        '\\?\unc\
        If filePath.Substring(0, 2) <> "\\" Then
            filePath = "\\?\" & filePath
            parentFolderPath = "\\?\" & parentFolderPath
        Else
            filePath = "\\?\UNC\" & filePath.Remove(0, 2)
            parentFolderPath = "\\?\UNC\" & parentFolderPath.Remove(0, 2)
        End If

        Dim result As String = "success"
        Dim newPath As String = parentFolderPath & "\" & newName


        If folderMode = False Then
            Dim index As Integer = newName.IndexOfAny(Path.GetInvalidFileNameChars)
            If index <> -1 Then
                Dim badChar As String = newName(index)
                Return "File name given contains invalid character(s):  " & badChar
            End If

            If File.Exists(newPath) Then
                result = "New name given already exists"
            ElseIf File.Exists(filePath) Then
                Try
                    File.Move(filePath, newPath)
                Catch ex As Exception
                    If ex.HResult = -2147024891 Then 'access denied error
                        Dim success As Boolean = cmdMove(filePath, newPath) 'SMB paths often generate erroneus access denied errors. The cmd command often works instead.
                        If success = True Then
                            Return "success:cmdMove used."
                        End If
                    End If
                    result = ex.Message
                End Try

            Else
                result = "Selected file no longer exists or failed to detect."
            End If


        Else 'if folderMode = True
            Dim index As Integer = newName.IndexOfAny(Path.GetInvalidPathChars)

            If index <> -1 Then
                Dim badChar As String = newName(index)
                Return "Folder name given contains invalid character(s):  " & badChar
            End If

            If Directory.Exists(newPath) Then
                result = "New name given already exists"

            ElseIf Directory.Exists(filePath) Then
                Try
                    Directory.Move(filePath, newPath)
                Catch ex As Exception
                    If ex.HResult = -2147024891 Then 'access denied error
                        Dim success As Boolean = cmdMove(filePath, newPath)
                        If success = True Then
                            Return "success:cmdMove used."
                        End If
                    End If
                    result = ex.Message
                End Try

            Else
                result = "Selected folder no longer exists or failed to detect."
            End If

        End If

        Return result
    End Function

    Public Function cmdMove(src As String, dest As String) As Boolean

        Dim cmd As String = $"move ""{src}"" ""{dest}"""

        Dim psi As New ProcessStartInfo With {
            .FileName = "cmd.exe",
            .Arguments = "/c " & cmd,
            .CreateNoWindow = True,
            .UseShellExecute = False,
            .RedirectStandardError = True,
            .RedirectStandardOutput = True
        }

        Dim proc As Process = Process.Start(psi)
        proc.WaitForExit()

        Dim output As String = proc.StandardOutput.ReadToEnd()
        Dim err As String = proc.StandardError.ReadToEnd()

        If proc.ExitCode = 0 Then
            Return True
        Else
            Return False
        End If

    End Function


    Public Sub WriteToTextFile(txtName As String, contentStr As String) 'If full path isn't given, will write to EXE directory

        Dim filePath As String
        If txtName.Contains("\") = True Then
            filePath = txtName
        Else
            Dim exeFolder As String = Path.GetDirectoryName(Reflection.Assembly.GetExecutingAssembly().Location)
            filePath = Path.Combine(exeFolder, txtName)
        End If

        File.WriteAllText(filePath, contentStr)

    End Sub

    Public Sub OpenTxtFile(txtPath As String)

        Dim processInfo As New Diagnostics.ProcessStartInfo(txtPath) With {
            .UseShellExecute = True
        }
        Diagnostics.Process.Start(processInfo)
    End Sub

End Module